概述

對于運維有時在排查網絡問題時需要去查看進程使用的端口，下面整了一個bat腳本，主要利用netstat命令找出使用TCP協議通信的端口，并將結果分割；將第二個參數(IP加端口)傳給%%i，第五個參數(PID號)傳給%%j;

下面介紹下腳本內容。

bat腳本內容：

@echo off 
color 1f 
Title XP端口-進程查詢 
setlocal enabledelayedexpansion 
echo ╔- -╗ 
echo 本機開放的端口及使用該端口的進程 
echo ╚- -╝ 
echo ------------------------------------ 
echo 端口號 進程名稱 
ECHO TCP協議: 
::利用netstat命令找出使用TCP協議通信的端口，并將結果分割； 
::將第二個參數(IP加端口)傳給%%i，第五個參數(PID號)傳給%%j; 
for /F "usebackq skip=4 tokens=2,5" %%i in (`"netstat -ano -p TCP"`) do ( 
 call :Assoc %%i TCP %%j 
 echo !TCP_Port! !TCP_Proc_Name! 
) 
ECHO UDP協議: 
for /F "usebackq skip=4 tokens=2,4" %%i in (`"netstat -ano -p UDP"`) do ( 
 call :Assoc %%i UDP %%j 
 echo !UDP_Port! !UDP_Proc_Name! 
) 
echo 按任意鍵退出 
pause>nul 
:Assoc 
::對%1(第一個參數）進行分割，將第二個參數傳給%%e。在本程序中，%1即為上面的%%i(形式為：IP:端口號) 
for /F "tokens=2 delims=:" %%e in ("%1") do ( 
 set %2_Port=%%e 
 ) 
:: 查詢PID等于%3(第三個參數)的進程，并將結果傳給變量?_Proc_Name,?代表UDP或者TCP； 
for /F "skip=2 usebackq delims=, tokens=1" %%a in (`"Tasklist /FI "PID eq %3" /FO CSV"`) do ( 
 ::%%~a表示去掉%%a外面的引號，因為上述命令的結果是用括號括起來的。 
 set %2_Proc_Name=%%~a 
 ) 

在這里大家只需要新建一個txt，復制上面代碼后修改后綴名為bat(本來為txt),然后右鍵以管理員身份運行就可以了。

運行結果：